#delimit ;
version 8.0 ;
clear ;
set mem 400m ;
set more off ;
cap log close ;


*********************************************************
*
*	PROGRAMA PARA LA CONSTRUCCIÓN DEL ÍNDICE DE LA
*	TENDENCIA LABORAL DE LA POBREZA, INTERVALOS DE SALARIO
*
*********************************************************

Este programa debe ser utilizado con el Software Stata 
versión 8 o superior. 

Todas las bases de datos sociodemográficas de la Encuesta Nacional 
de Ocupación y Empleo (ENOE) pueden ser obtenidas en la página de 
Internet del INEGI, www.inegi.gob.mx, y deben estar convertidas a 
formato *.dta. Para esta estimación, de las bases de microdatos 
disponibles de la ENOE se emplean las siguientes: sdem.dta y coe2.dta.

En este programa se utilizan cuatro tipos de archivos, los cuales 
están ubicados en las siguientes carpetas:

1) Bases originales sociodemográficas: "C:\ITLP IS\sdem"
1) Bases originales cuestionario ocupación y empleo 2: "C:\ITLP IS\coe2"
2) Bases generadas: "C:\ITLP IS\temp"
3) Bitácoras: "C:\ITLP IS\log"

Para cambiar estas ubicaciones, se modifican los siguientes
globals; 

gl enoe = "C:\ITLP_IS\sdem" ;
gl coe2 = "C:\ITLP_IS\coe2";
gl temp = "C:\ITLP_IS\Temp" ;
gl log  = "C:\ITLP_IS\Log" ;

log using "$log\ITLP IS.smcl", replace ;

set obs 1 ;
gen periodo = . ;
gen TLP = . ;
save "$temp\Indice ESTADOS IS.dta", replace ;


*********************************************************

Parte I, LÍNEA DE BIENESTAR MÍNIMO :

********************************************************* ;


di in red "Promedio trimestral de los valores de la línea de bienestar mínimo" ;

scalar ut108 = 839.20 ;
scalar rt108 = 585.95 ;
scalar ut208 = 858.25 ;
scalar rt208 = 601.31 ;
scalar ut308 = 875.53 ;
scalar rt308 = 614.68 ;
scalar ut408 = 906.74 ;
scalar rt408 = 640.52 ;

scalar ut109 = 921.95 ;
scalar rt109 = 648.99 ;
scalar ut209 = 949.80 ;
scalar rt209 = 672.94 ;
scalar ut309 = 967.59 ;
scalar rt309 = 686.42 ;
scalar ut409 = 968.88 ;
scalar rt409 = 686.07 ;


scalar ut110 = 992.66 ;
scalar rt110 = 705.15 ;
scalar ut210 = 987.37 ;
scalar rt210 = 695.86 ;
scalar ut310 = 979.48 ;
scalar rt310 = 685.00 ;
scalar ut410 = 1003.55;
scalar rt410 = 705.69 ;

scalar ut111 = 1021.46;
scalar rt111 = 717.37 ;
scalar ut211 = 1022.32;
scalar rt211 = 717.89 ;
scalar ut311 = 1023.18;
scalar rt311 = 716.95 ;
scalar ut411 = 1049.23;
scalar rt411 = 740.46 ;

scalar ut112 = 1079.48;
scalar rt112 = 765.39 ;
scalar ut212 = 1089.06;
scalar rt212 = 770.99 ;
scalar ut312 = 1130.12;
scalar rt312 = 805.78 ;
scalar ut412 = 1151.73;
scalar rt412 =  820.37;

scalar ut113 = 1166.19;
scalar rt113 = 828.58 ;
scalar ut213 = 1177.37;
scalar rt213 = 837.17 ;
scalar ut313 = 1177.92;
scalar rt313 = 833.29 ;
scalar ut413 = 1202.03;
scalar rt413 = 853.78 ;


*********************************************************

Parte II CÁLCULO DEL INGRESO DE LOS HOGARES :

********************************************************* ;

foreach x in t108 t208 t308 t408
		 t109 t209 t309 t409
		 t110 t210 t310 t410 
	     	 t111 t211 t311 t411
		 t112 t212 t312 t412	
		 t113 t213 t313 t413 { ;

use "$coe2\coe2`x'.dta" , clear;
gen str foliop = (cd_a + ent + con + v_sel + n_hog + h_mud + n_ren);
keep foliop p6c p6b2 p6_9 p6a3;
sort foliop;

save "$temp\ingreso`x'.dta", replace;

use "$enoe\sdem`x'.dta", clear ;
keep if r_def=="00" & (c_res=="1" | c_res=="3") ;

gen str folioh = (cd_a + ent + con + v_sel + n_hog + h_mud);
gen str foliop = (cd_a + ent + con + v_sel + n_hog + h_mud+n_ren);

keep folioh foliop salario t_loc fac clase1 clase2 ent ingocup;
sort foliop;
merge foliop using "$temp\ingreso`x'.dta";
tab _merge;
drop _merge;

gen ocupado=cond(clase1==1 & clase2==1,1,0);

destring p6b2 p6c, replace;
recode p6b2 (999998=.) (999999=.);

*Recuperación de ingresos por rangos de salarios mínimos;
gen ingreso=p6b2;
replace ingreso=0 if ocupado==0;
replace ingreso=0 if p6b2==. & (p6_9=="09" | p6a3=="3");
replace ingreso=0.5*salario if p6b2==. & p6c==1;
replace ingreso=1*salario if p6b2==. & p6c==2;
replace ingreso=1.5*salario if p6b2==. & p6c==3;
replace ingreso=2.5*salario if p6b2==. & p6c==4;
replace ingreso=4*salario if p6b2==. & p6c==5;
replace ingreso=7.5*salario if p6b2==. & p6c==6;
replace ingreso=10*salario if p6b2==. & p6c==7;

gen tamh = 1 ; 
rename fac factor ;
gen rururb = cond(t_loc>="1" & t_loc<="3",0,1) ;
label define ru 0 "Urbano" 1 "Rural" ;
label values rururb ru ;
destring ent, replace;

gen mv=cond(ingreso==. & ocupado==1,1,0);

keep folioh tamh ingreso rururb factor ent mv ocupado;
collapse 
(sum) tamh ingreso mv ocupado (mean) rururb factor ent, 
by(folioh) ;

*Se elimina a los hogares que tienen valores perdidos en ingreso;

replace mv=1 if mv>0 & mv!=.;
drop if mv==1;

*********************************************************

Parte III COMPARACIÓN DEL INGRESO DEL HOGAR CON 
	EL PROMEDIO DE LA LINEA DE BIENESTAR MÍNIMO :

********************************************************* ;

gen factorp = factor*tamh ;

gen lp`x' = cond(rururb==0,u`x',r`x') ;
gen pob = cond((ingreso/tamh)<lp`x',1,0) ;

sum pob [w=factorp] ;
gen TLP=r(mean)*100;
format TLP %6.4f;

sum pob [w=factorp] if rururb==0 ;
gen TLPu=r(mean)*100;
format TLPu %6.4f;

sum pob [w=factorp] if rururb==1 ;
gen TLPr=r(mean)*100;
format TLPr %6.4f;

foreach y in 1  2  3  4  5  6  7  8  9 10 
		11 12 13 14 15 16 17 18 19 20
		21 22 23 24 25 26 27 28 29 30 
		31 32 { ;

sum pob [w=factorp] if ent==`y' ;
gen TLP`y'=r(mean)*100;
format TLP`y' %6.4f;

};

gen periodo="`x'" ;

keep TLP* periodo;
keep in 1 ;

append using "$temp\Indice ESTADOS IS.dta";
save "$temp\Indice ESTADOS IS.dta", replace ;

} ;


*********************************************************

Parte IV CÁLCULO DEL ÍNDICE DE LA TENDENCIA 
	LABORAL DE LA POBREZA :

********************************************************* ;

drop if TLP==. ;
gen per=substr(periodo,2,3) ;
drop periodo ;
rename per periodo ;
destring periodo, replace ;
label var periodo "Trimestre" ;

sum TLP if periodo==110 ;
gen base=r(mean) ;
format base %6.4f ;
gen ITLP=. ;
replace ITLP=TLP/base ;
label var ITLP "Valor del índice de la tendencia laboral de la pobreza" ;
format ITLP %6.4f ;

sum TLPu if periodo==110 ;
gen baseu=r(mean) ;
format baseu %6.4f ;
gen ITLPu=. ;
replace ITLPu=TLPu/baseu ;
label var ITLPu "Valor del índice de la tendencia laboral de la pobreza urbano" ;
format ITLPu %6.4f ;

sum TLPr if periodo==110 ;
gen baser=r(mean) ;
format baser %6.4f ;
gen ITLPr=. ;
replace ITLPr=TLPr/baser ;
label var ITLPr "Valor del índice de la tendencia laboral de la pobreza rural" ;
format ITLPr %6.4f ;

foreach z in  1  2  3  4  5  6  7  8  9 10 
	     11 12 13 14 15 16 17 18 19 20
	     21 22 23 24 25 26 27 28 29 30 
	     31 32 { ;

sum TLP`z' if periodo==110 ;
gen base`z'=r(mean) ;
format base`z' %6.4f ;
gen ITLP`z'=. ;
replace ITLP`z'=TLP`z'/base`z' ;
label var ITLP`z' "Valor del índice de la tendencia laboral de la pobreza `z'" ;
format ITLP`z' %6.4f ;

};

gen orden=_n ;
gsort -orden ;
keep periodo ITLP*;

label define periodo
108 "I 2008"
208 "II 2008"
308 "III 2008"
408 "IV 2008"
109 "I 2009"
209 "II 2009"
309 "III 2009"
409 "IV 2009"
110 "I 2010" 
210 "II 2010" 
310 "III 2010" 
410 "IV 2010"
111 "I 2011"
211 "II 2011"
311 "III 2011"
411 "IV 2011"
112 "I 2012"
212 "II 2012"
312 "III 2012"
313 "III 2013"
412 "IV 2012"
113 "I 2013"
213 "II 2013"
313 "III 2013"
413 "IV 2013";

label value periodo periodo ;

rename ITLP Nacional ;
rename ITLPu Urbano ;
rename ITLPr Rural ;
rename ITLP1 Aguascalientes ;
rename ITLP2 Baja_California ;
rename ITLP3 Baja_California_Sur ;
rename ITLP4 Campeche ;
rename ITLP5 Coahuila ;
rename ITLP6 Colima ;
rename ITLP7 Chiapas ;
rename ITLP8 Chihuahua ;
rename ITLP9 Distrito_Federal ;
rename ITLP10 Durango ;
rename ITLP11 Guanajuato ;
rename ITLP12 Guerrero ;
rename ITLP13 Hidalgo ;
rename ITLP14 Jalisco ;
rename ITLP15 Estado_de_México ;
rename ITLP16 Michoacán ;
rename ITLP17 Morelos ;
rename ITLP18 Nayarit ;
rename ITLP19 Nuevo_León ;
rename ITLP20 Oaxaca ;
rename ITLP21 Puebla ;
rename ITLP22 Querétaro ;
rename ITLP23 Quintana_Roo ;
rename ITLP24 San_Luis_Potosí ;
rename ITLP25 Sinaloa ;
rename ITLP26 Sonora ;
rename ITLP27 Tabasco ;
rename ITLP28 Tamaulipas ;
rename ITLP29 Tlaxcala ;
rename ITLP30 Veracruz ;
rename ITLP31 Yucatán ;
rename ITLP32 Zacatecas ;

tabstat  Nacional- Zacatecas, by (per) format(%6.2f) nototal;
save "$temp\ITLP IS.dta", replace ;
scalar list;
log close ;