#delimit ;
version 8.0 ;
clear ;
set mem 400m ;
set more off ;
cap log close ;


*********************************************************
*
*	PROGRAMA PARA LA CONSTRUCCIÓN DEL INDICADOR DE
*	TENDENCIA LABORAL DE LA POBREZA
*
*********************************************************

Este programa debe ser utilizado con el Software Stata 
versión 8 o superior. 

Todas las bases de datos sociodemográficas de la Encuesta Nacional 
de Ocupación y Empleo (ENOE) pueden ser obtenidas en la página de 
Internet del INEGI, www.inegi.gob.mx, y deben estar convertidas a 
formato *.dta. De todas las bases de microdatos disponibles de la 
ENOE solamente se emplea sdem.dta.

En este programa se utilizan tres tipos de archivos, los cuales 
están ubicados en las siguientes carpetas:

1) Bases originales: "C:\Indicador de tendencia laboral de la pobreza\sdem"
2) Bases generadas: "C:\Indicador de tendencia laboral de la pobreza\temp"
3) Bitácoras: "C:\Indicador de tendencia laboral de la pobreza\log"

Para cambiar estas ubicaciones, se modifican los siguientes
globals; 

gl enoe = "C:\Indicador de tendencia laboral de la pobreza\sdem" ;
gl temp = "C:\Indicador de tendencia laboral de la pobreza\temp" ;
gl log  = "C:\Indicador de tendencia laboral de la pobreza\log" ;

log using "$log\indicador de tendencia laboral de la pobreza por entidades federativas.smcl", replace ;

set obs 1 ;
gen periodo = . ;
gen TLP = . ;
save "$temp\indicador ESTADOS.dta", replace ;


*********************************************************

Parte I, LÍNEA DE BIENESTAR MÍNIMO :

********************************************************* ;


di in red "Promedio trimestral de los valores de la línea de bienestar mínimo" ;

scalar ut105 = 712.55 ;
scalar rt105 = 492.79 ;
scalar ut205 = 741.44 ;
scalar rt205 = 519.99 ;
scalar ut305 = 740.43 ;
scalar rt305 = 516.88 ;
scalar ut405 = 736.46 ;
scalar rt405 = 510.00 ;

scalar ut106 = 754.22 ;
scalar rt106 = 526.50 ;
scalar ut206 = 748.59 ;
scalar rt206 = 518.16 ;
scalar ut306 = 764.23 ;
scalar rt306 = 533.34 ;
scalar ut406 = 797.66 ;
scalar rt406 = 565.58 ;

scalar ut107 = 814.62 ;
scalar rt107 = 576.38 ;
scalar ut207 = 803.91 ;
scalar rt207 = 563.68 ;
scalar ut307 = 810.81 ;
scalar rt307 = 567.73 ;
scalar ut407 = 830.53 ;
scalar rt407 = 582.77 ;

scalar ut108 = 839.20 ;
scalar rt108 = 585.94 ;
scalar ut208 = 858.20 ;
scalar rt208 = 601.24 ;
scalar ut308 = 875.45 ;
scalar rt308 = 614.59 ;
scalar ut408 = 906.68 ;
scalar rt408 = 640.42 ;

scalar ut109 = 921.98 ;
scalar rt109 = 648.97 ;
scalar ut209 = 949.95 ;
scalar rt209 = 673.02 ;
scalar ut309 = 967.79 ;
scalar rt309 = 686.56 ;
scalar ut409 = 969.03 ;
scalar rt409 = 686.15 ;

scalar ut110 = 992.71 ;
scalar rt110 = 705.16 ;
scalar ut210 = 987.39 ;
scalar rt210 = 695.84 ;
scalar ut310 = 979.65 ;
scalar rt310 = 685.10 ;



*********************************************************

Parte II CÁLCULO DEL INGRESO DE LOS HOGARES :

********************************************************* ;

foreach x in t105 t205 t305 t405
	       t106 t206 t306 t406 
	       t107 t207 t307 t407 
	       t108 t208 t308 t408 
	       t109 t209 t309 t409 
	       t110 t210 t310      { ;

local d = substr("`x'",4,1) ;
use "$enoe\sdem`x'.dta", clear ;
keep if r_def=="00" & (c_res=="1" | c_res=="3") ;
gen tamh = 1 ; 
gen str folioh = (cd_a + ent + con + v_sel + n_hog + h_mud) ;
rename fac factor ;
rename ingocup ingreso ;
gen rururb = cond(t_loc>="1" & t_loc<="3",0,1) ;
label define ru 0 "Urbano" 1 "Rural" ;
label values rururb ru ;
destring ent, replace;
keep folioh tamh ingreso rururb factor ent;
collapse 
(sum) tamh ingreso (mean) rururb factor ent, 
by(folioh) ;

*********************************************************

Parte III COMPARACIÓN DEL INGRESO DEL HOGAR CON 
	EL PROMEDIO DE LA LINEA DE BIENESTAR MÍNIMO :

********************************************************* ;


gen lp`x' = cond(rururb==0,u`x',r`x') ;
gen pob = cond((ingreso/tamh)<lp`x',1,0) ;
gen factorp = factor*tamh ;

sum pob [w=factorp] ;
gen TLP=r(mean)*100;
format TLP %6.4f;

sum pob [w=factorp] if rururb==0 ;
gen TLPu=r(mean)*100;
format TLPu %6.4f;

sum pob [w=factorp] if rururb==1 ;
gen TLPr=r(mean)*100;
format TLPr %6.4f;

foreach y in 1  2  3  4  5  6  7  8  9 10 
		11 12 13 14 15 16 17 18 19 20
		21 22 23 24 25 26 27 28 29 30 
		31 32 { ;

sum pob [w=factorp] if ent==`y' ;
gen TLP`y'=r(mean)*100;
format TLP`y' %6.4f;

};


gen periodo="`x'" ;

keep TLP* periodo ;
keep in 1 ;

append using "$temp\indicador ESTADOS.dta";
save "$temp\indicador ESTADOS.dta", replace ;

} ;


*********************************************************

Parte IV CÁLCULO DEL INDICADOR DE LA TENDENCIA 
	LABORAL DE LA POBREZA :

********************************************************* ;

drop if TLP==. ;
gen per=substr(periodo,2,3) ;
drop periodo ;
rename per periodo ;
destring periodo, replace ;
label var periodo "Trimestre" ;

sum TLP if periodo==105 ;
gen base=r(mean) ;
format base %6.4f ;
gen ITLP=. ;
replace ITLP=TLP/base ;
label var ITLP "Valor del indicador de tendencia laboral de la pobreza" ;
format ITLP %6.4f ;

sum TLPu if periodo==105 ;
gen baseu=r(mean) ;
format baseu %6.4f ;
gen ITLPu=. ;
replace ITLPu=TLPu/baseu ;
label var ITLPu "Valor del indicador de tendencia laboral de la pobreza urbano" ;
format ITLPu %6.4f ;

sum TLPr if periodo==105 ;
gen baser=r(mean) ;
format baser %6.4f ;
gen ITLPr=. ;
replace ITLPr=TLPr/baser ;
label var ITLPr "Valor del indicador de tendencia laboral de la pobreza rural" ;
format ITLPr %6.4f ;

foreach z in  1  2  3  4  5  6  7  8  9 10 
	     11 12 13 14 15 16 17 18 19 20
	     21 22 23 24 25 26 27 28 29 30 
	     31 32 { ;

sum TLP`z' if periodo==105 ;
gen base`z'=r(mean) ;
format base`z' %6.4f ;
gen ITLP`z'=. ;
replace ITLP`z'=TLP`z'/base`z' ;
label var ITLP`z' "Valor del indicador de tendencia laboral de la pobreza `z'" ;
format ITLP`z' %6.4f ;

};

gen orden=_n ;
gsort -orden ;
keep periodo ITLP* ;

label define periodo
105 "I 2005"
205 "II 2005"
305 "III 2005"
405 "IV 2005"
106 "I 2006"
206 "II 2006"
306 "III 2006"
406 "IV 2006"
107 "I 2007"
207 "II 2007"
307 "III 2007"
407 "IV 2007"
108 "I 2008"
208 "II 2008"
308 "III 2008"
408 "IV 2008"
109 "I 2009"
209 "II 2009"
309 "III 2009"
409 "IV 2009" 
110 "I 2010" 
210 "II 2010" 
310 "III 2010" ;


label value periodo periodo ;

rename ITLP Nacional ;
rename ITLPu Urbano ;
rename ITLPr Rural ;
rename ITLP1 Aguascalientes ;
rename ITLP2 Baja_California ;
rename ITLP3 Baja_California_Sur ;
rename ITLP4 Campeche ;
rename ITLP5 Coahuila ;
rename ITLP6 Colima ;
rename ITLP7 Chiapas ;
rename ITLP8 Chihuahua ;
rename ITLP9 Distrito_Federal ;
rename ITLP10 Durango ;
rename ITLP11 Guanajuato ;
rename ITLP12 Guerrero ;
rename ITLP13 Hidalgo ;
rename ITLP14 Jalisco ;
rename ITLP15 Estado_de_México ;
rename ITLP16 Michoacán ;
rename ITLP17 Morelos ;
rename ITLP18 Nayarit ;
rename ITLP19 Nuevo_León ;
rename ITLP20 Oaxaca ;
rename ITLP21 Puebla ;
rename ITLP22 Querétaro ;
rename ITLP23 Quintana_Roo ;
rename ITLP24 San_Luis_Potosí ;
rename ITLP25 Sinaloa ;
rename ITLP26 Sonora ;
rename ITLP27 Tabasco ;
rename ITLP28 Tamaulipas ;
rename ITLP29 Tlaxcala ;
rename ITLP30 Veracruz ;
rename ITLP31 Yucatán ;
rename ITLP32 Zacatecas ;


tabstat  Nacional- Zacatecas, by (per) format(%6.2f) nototal;

log close ;